' СОРС ЗА ФОРМАТА

Public MyNumber As AnyNumBase ' Декларация на обекта MyNumber

 

' При въведждане на формата

Private Sub Form_Load()

    Set MyNumber = New AnyNumBase ' Създаваме нов клас с име MyNumber от типа AnyNumBase

End Sub

 

' При извеждане на формата

Private Sub Form_Unload(Cancel As Integer)

    Set MyNumber = Nothing ' Унищожваме класа с име MyNumber

End Sub

 

' При сработване на клавиш в горно положение на текстовото поле txtBinary

Private Sub txtBinary_KeyUp(KeyCode As Integer, Shift As Integer)

    MyNumber.BinNum = txtBinary ' Зареждаме свойството BinNum на класа MyNumber с двоичното число

    ' Записваме в другите две текстови полета получените преобразувани свойства на MyNumber за десетично и шестнайсетично число

    txtDec = MyNumber.DeciNum

    txtHex = MyNumber.HexNum

End Sub

 

' При сработване на клавиш в горно положение на текстовото поле txtDec

Private Sub txtDec_KeyUp(KeyCode As Integer, Shift As Integer)

    MyNumber.DeciNum = txtDec ' Зареждаме свойството DeciNum на класа MyNumber с десетичното число

    ' Записваме в другите две текстови полета получените преобразувани свойства на MyNumber за шестнайсетично и двоично число

    txtHex = MyNumber.HexNum

    txtBinary = MyNumber.BinNum

End Sub

 

' При сработване на клавиш в горно положение на текстовото поле txtHex

Private Sub txtHex_KeyUp(KeyCode As Integer, Shift As Integer)

    MyNumber.HexNum = txtHex ' Зареждаме свойството HexNum на класа MyNumber с шеснайсетично число

    ' Записваме в другите две текстови полета получените преобразувани свойства на MyNumber за десетично и двоично число

    txtDec = MyNumber.DeciNum

    txtBinary = MyNumber.BinNum

End Sub

 

' СОРС ЗА КЛАСА AnyNumBase

 

Private mlNumber As Long

 

 

Public Property Let DeciNum(DecNumber As Long)

    mlNumber = DecNumber

End Property

 

Public Property Get DeciNum() As Long

    DeciNum = mlNumber

End Property

 

Public Property Let BinNum(BinNumber As String)

   

Dim i As Long

Dim sBinChar As String

Dim lLength As Long

Dim lPosiValue As Long

   

    lLength = Len(BinNumber)

    mlNumber = 0

    For i = lLength To 1 Step -1

        sBinChar = Mid(BinNumber, i, 1)

        lPosiValue = CLng(sBinChar) * (2 ^ (lLength - i))

        mlNumber = mlNumber + lPosiValue

    Next

   

End Property

 

Public Property Get BinNum() As String

 

Dim sHex As String

Dim i As Long

Dim lCount As Long

 

    sHex = Hex(mlNumber)

    lCount = Len(sHex)

    BinNum = ""

   

    For i = 1 To lCount

        BinNum = BinNum & HexToBinChart(Mid(sHex, i, 1))

    Next

       

End Property

 

Public Property Let HexNum(HexNumber As String)

   

Dim i As Long

Dim sHexChar As String

Dim lLength As Long

Dim lPosiValue As Long

   

    lLength = Len(HexNumber)

    mlNumber = 0

    For i = lLength To 1 Step -1

        sHexChar = Mid(HexNumber, i, 1)

        lPosiValue = HexToDecChart(sHexChar) * (16 ^ (lLength - i))

        mlNumber = mlNumber + lPosiValue

    Next

   

End Property

 

Public Property Get HexNum() As String

    HexNum = Hex(mlNumber)

End Property

 

Private Function HexToBinChart(HexCode As String) As String

 

    Select Case UCase(HexCode)

    Case "0": HexToBinChart = "0000"

    Case "1": HexToBinChart = "0001"

    Case "2": HexToBinChart = "0010"

    Case "3": HexToBinChart = "0011"

 

    Case "4": HexToBinChart = "0100"

    Case "5": HexToBinChart = "0101"

    Case "6": HexToBinChart = "0110"

    Case "7": HexToBinChart = "0111"

 

    Case "8": HexToBinChart = "1000"

    Case "9": HexToBinChart = "1001"

    Case "A": HexToBinChart = "1010"

    Case "B": HexToBinChart = "1011"

 

    Case "C": HexToBinChart = "1100"

    Case "D": HexToBinChart = "1101"

    Case "E": HexToBinChart = "1110"

    Case "F": HexToBinChart = "1111"

 

    End Select

 

End Function

 

Private Function HexToDecChart(HexCode As String) As Long

 

    Select Case UCase(HexCode)

    Case "0": HexToDecChart = 0

    Case "1": HexToDecChart = 1

    Case "2": HexToDecChart = 2

    Case "3": HexToDecChart = 3

 

    Case "4": HexToDecChart = 4

    Case "5": HexToDecChart = 5

    Case "6": HexToDecChart = 6

    Case "7": HexToDecChart = 7

 

    Case "8": HexToDecChart = 8

    Case "9": HexToDecChart = 9

    Case "A": HexToDecChart = 10

    Case "B": HexToDecChart = 11

 

    Case "C": HexToDecChart = 12

    Case "D": HexToDecChart = 13

    Case "E": HexToDecChart = 14

    Case "F": HexToDecChart = 15

 

    End Select

 

End Function